MINLOC

Intel® Fortran Compiler Classic and Intel® Fortran Compiler Developer Guide and Reference

Download PDF

ID 767251

Date 6/24/2024

Version

Public

A newer version of this document is available. Customers should click here to go to the newest version.

Visible to Intel only — GUID: GUID-5CB257ED-9CC1-4B0A-97B4-2EE45C4E5C4A

View Details

MINLOC

Transformational Intrinsic Function (Generic): Returns the location of the minimum value of all elements in an array, a set of elements in an array, or elements in a specified dimension of an array.

result = MINLOC (array, dim [, mask, kind, back])

result = MINLOC (array [, mask, kind, back])

array	(Input) Must be an array of type integer, real, or character. Note that the Fortran standard does not define the behavior of this function if `array` is a real type and one or more elements is a Nan.
dim	(Input) Must be a scalar integer with a value in the range 1 to `n`, where `n` is the rank of `array`.
mask	(Input; optional) Must be a logical array that is conformable with `array`.
kind	(Input; optional) Must be a scalar integer constant expression.
back	(Input; optional) Must be a scalar of type logical.

Results

The result is an array of type integer. If kind is present, the kind parameter of the result is that specified by kind; otherwise, the kind parameter of the result is that of default integer. If the processor cannot represent the result value in the kind of the result, the result is undefined.

The following rules apply if dim is not specified:

The array result has rank one and a size equal to the rank of array.
If MINLOC(array) is specified, the elements in the array result form the subscript of the location of the element with the minimum value in array.

The ith subscript returned lies in the range 1 to e_i, where e_i is the extent of the ith dimension of array.
If MINLOC(array, MASK= mask) is specified, the elements in the array result form the subscript of the location of the element with the minimum value corresponding to the condition specified by mask.

The following rules apply if dim is specified:

The array result has a rank that is one less than array, and shape (d₁, d₂,...d_dim-1, d_dim+1,...d_n), where (d₁, d₂,...d_n) is the shape of array.
If array has rank one, MINLOC( array, dim [, mask]) is a scalar and has a value equal to the first element of MINLOC( array [,MASK = mask]). Otherwise, the value of element (s₁, s₂,...s_dim-1, s_dim+1,...s_n) of MINLOC( array, dim [, mask]) is equal to MINLOC( array(s₁, s₂,...s_dim-1, :, s_dim+1,...s_n) [, MASK = mask(s₁, s₂,...s_dim-1, :, s_dim+1,...s_n)]).

If only one element has the minimum value, that element’s subscripts are returned. Otherwise, if more than one element has the minimum value and back is absent or present with the value .FALSE., the element whose subscripts are returned is the first such element, taken in array element order. If back is present with the value .TRUE., the element whose subscripts are returned is the last such element, taken in array element order.

If array has size zero, or every element of mask has the value .FALSE., the value of the result is controlled by compiler option assume [no]old_maxminloc, which can set the value of the result to either 1 or 0.

If array is of type character, the comparison is done using the ASCII collating sequence.

The setting of compiler options specifying integer size can affect this function.

Example

The value of MINLOC ((/3, 1, 4, 1/)) is (2), which is the subscript of the location of the first occurrence of the minimum value in the rank-one array.

A is the array

  [  4    0   0    2 ]
  [  3   -6   -2    6 ]
  [ -1   -4    5   -4 ].

MINLOC (A, MASK=A .GT. -5) has the value (3, 2) because these are the subscripts of the location of the first minimum value (-4) that is greater than -5.

MINLOC (A, DIM=1) has the value (3, 2, 2, 3). 3 is the subscript of the location of the first minimum value (-1) in column 1; 3 is the subscript of the location of the first minimum value (-6) in column 2; and so forth.

MINLOC (A, DIM=2) has the value (2, 2, 2). 2 is the subscript of the location of the first minimum value (0) in row 1; 2 is the subscript of the location of the first minimum value (-6) in row 2; and so forth.

MINLOC (A, DIM=2, BACK=.TRUE.) has the value (3, 2, 4). 3 is the subscript of the location of the last minimum value (0) in row 1; 2 is the subscript of the location of the last minimum value (-6) in row 2; and so forth.

The following shows another example:


 INTEGER i, minl(1)
 INTEGER array(2, 3)
 INTEGER, ALLOCATABLE :: AR1(:)
 ! put values in array
 array = RESHAPE((/-7, 1, -2, -9, 5, 0/),(/2, 3/))
 !   array is   -7 -2 5
 !               1 -9 0
 i = SIZE(SHAPE(array))  ! Get the number of dimensions
                         !   in array
 ALLOCATE (AR1 (i))      ! Allocate AR1 to number
                         !   of dimensions in array
 AR1 = MINLOC (array, MASK = array .GT. -5)   ! Get the
                         !   location (subscripts) of
                         !   smallest element greater
                         !   than -5 in array

 !
 ! MASK = array .GT. -5 creates a mask array the same
 ! size and shape as array whose elements are .TRUE. if
 ! the corresponding element in array is greater than
 ! -5, and .FALSE. if it is not. This mask causes MINLOC
 ! to return the index of the element in array with the
 ! smallest value greater than -5.
 !
 !array is  -7 -2 5 and MASK= array .GT. -5 is  F T T
 !           1 -9 0                             T F T
 ! and AR1 = MINLOC(array, MASK = array .GT. -5) returns
 ! (1, 2), the location of the element with value -2

 minl = MINLOC((/-7,2,-7,5/))   ! returns 1, first
                                ! occurrence of minimum
 END

Parent topic: M to N

Select Your Language

Using Intel.com Search

Quick Links

Recent Searches

Advanced Search

Only search in

Intel® Fortran Compiler Classic and Intel® Fortran Compiler Developer Guide and Reference

MINLOC

Results

Example

See Also